SICP問題2.84

問題2.83のraise演算を使ってapply-generic手続き修正し、順次高めていく方法で、引数を同じ型になるまで、強制変換するようにせよ。
二つの型のいずれが塔の中で高いかをテストする方法をシステムの他の部分と「整合している」方法で行い、塔に新レベルを追加する時の問題を生じないようにせよ。

まず raise を apply-generic を使わない形に変更

(define (raise x)
    (let ((proc (get 'raise (type-tag x))))
      (if proc
          (proc (contents x))
          x)))

二つの型のいずれが塔の中で高いかをテストする方法。
型の塔をリストとして作成しておく

(define tower-of-types '(integer rational real complex))
(define (higher? type1 type2)
  (define (index-of-tower target-type)
    (define (iter-index-of-tower types index)
      (if (pair? types)
	  (if (eq? target-type (car types))
	      index
	      (iter-index-of-tower (cdr types) (+ index 1)))
;; complex rectangler に対応できないのでコメントアウト
;;	  (error "This type not in tower of types -- HIGHER "
;;                         (list target-type))
	  index))
    (iter-index-of-tower tower-of-types 0))
  (let ((index1 (index-of-tower type1))
	(index2 (index-of-tower type2)))
    (if (> index1 index2)
	#t
	#f)))

修正版のapply-generic

(define (apply-generic op . args)
  (let ((type-tags (map type-tag args)))
    (define (highest type rest)
      (if (null? rest)
	  type
	  (if (higher? (car rest) type)
	      (highest (car rest) (cdr rest))
	      (highest type (cdr rest)))))
    (define (raise-to-target-type x target-type)
      (if (eq? (type-tag x) target-type)
	  x
	  (raise-to-target-type (raise x) target-type)))
    ;; 本体
    (let ((highest-type (highest (car type-tags) type-tags)))
      (let ((coerced-args 
	     (map (lambda(x) (raise-to-target-type x highest-type)) args)))
	(let ((coerced-tags (map type-tag coerced-args)))
	  (let ((proc (get op coerced-tags)))
	    (if proc
		(apply proc (map contents coerced-args))
		(error "No method for these types -- APPLY-GENERIC"
                         (list op type-tags))))))) ;; 本体
    ) ;; type-tags
  ) ;; apply-generc

修正版の演算パッケージ

; 汎用演算パッケージ
(define (add x y) (apply-generic 'add x y))
(define (sub x y) (apply-generic 'sub x y))
(define (mul x y) (apply-generic 'mul x y))
(define (div x y) (apply-generic 'div x y))
(define (equ? x y) (apply-generic 'equ? x y))
(define (=zero? x) (apply-generic '=zero? x))
;; (define (raise x) (apply-generic 'raise x))
(define (raise x)
    (let ((proc (get 'raise (type-tag x))))
      (if proc
          (proc (contents x))
          x)))

(define (install-integer-package)
  (define (tag x)
    (attach-tag 'integer x))
  (define (integer->rational n)
    (make-rational n 1))
  (put 'add '(integer integer)
       (lambda (x y) (tag (+ x y))))
  (put 'sub '(integer integer)
       (lambda (x y) (tag (- x y))))
  (put 'mul '(integer integer)
       (lambda (x y) (tag (* x y))))
  (put 'div '(integer integer)
       (lambda (x y) (tag (/ x y))))
  (put 'equ? '(integer integer)
       (lambda (x y) (= x y)))
  (put '=zero? '(integer)
       (lambda (x) (= x 0)))
  (put 'make 'integer
       (lambda (x) (tag x)))
  (put 'exp '(integer integer)
       (lambda (x y) (tag (expt x y))))
  ; 追加
  (put 'raise 'integer
       (lambda (x) (integer->rational x)))
  'done)
(install-integer-package)
(define (make-integer n)
  ((get 'make 'integer) n))

; 有理数算術演算
(define (install-rational-package)
  ;; 内部手続き
  (define (numer x) (car x))
  (define (denom x) (cdr x))
  (define (make-rat n d)
    (let ((g (gcd n d)))
      (cons (/ n g) (/ d g))))
  (define (add-rat x y)
    (make-rat (+ (* (numer x) (denom y))
		 (* (numer y) (denom x)))
	      (* (denom x) (denom y))))
  (define (sub-rat x y)
    (make-rat (- (* (numer x) (denom y))
		 (* (numer y) (denom x)))
	      (* (denom x) (denom y))))
  (define (mul-rat x y)
    (make-rat (* (numer x) (numer y))
	      (* (denom x) (denom y))))
  (define (div-rat x y)
    (make-rat (* (numer x) (denom y))
	      (* (denom x) (numer y))))
  (define (equ-rat x y)
    (= (* (numer x) (denom y))
       (* (numer y) (denom x))))
  (define (=zero-rat x)
    (and (= (numer x) 0)
	 (not (= (denom x) 0))))
  ;; システムの他の部分へのインタフェース
  (define (tag x) (attach-tag 'rational x))
  (define (rational->real x)
    (make-real (/ (numer x) (denom x))))
  (put 'add '(rational rational)
       (lambda (x y) (tag (add-rat x y))))
  (put 'sub '(rational rational)
       (lambda (x y) (tag (sub-rat x y))))
  (put 'mul '(rational rational)
       (lambda (x y) (tag (mul-rat x y))))
  (put 'div '(rational rational)
       (lambda (x y) (tag (div-rat x y))))
  (put 'equ? '(rational rational)
       (lambda (x y) (equ-rat x y)))
  (put '=zero? '(rational)
       (lambda (x) (=zero-rat x)))
  (put 'make 'rational
       (lambda (n d) (tag (make-rat n d))))
  ; 追加
  (put 'raise 'rational
       (lambda (x) (rational->real x)))
  'done)
(define (make-rational n d)
  ((get 'make 'rational) n d))

;; 実数パッケージ
(define (install-real-package)
  (define (tag x)
    (attach-tag 'real x))
  (define (real->complex x)
    (make-complex-from-real-imag x 0))
  (put 'add '(real real)
       (lambda (x y) (tag (+ x y))))
  (put 'sub '(real real)
       (lambda (x y) (tag (- x y))))
  (put 'mul '(real real)
       (lambda (x y) (tag (* x y))))
  (put 'div '(real real)
       (lambda (x y) (tag (/ x y))))
  (put 'equ? '(real real)
       (lambda (x y) (= x y)))
  (put '=zero? '(real)
       (lambda (x) (= x 0)))
  (put 'make 'real
       (lambda (x) (tag (* x 1.0)))) ;; rational->real で 1/3 とかになってしまうのでごまかし
  (put 'exp '(real real)
       (lambda (x y) (tag (expt x y))))
  ; 追加
  (put 'raise 'real
       (lambda (x) (real->complex x)))
  'done)
(install-real-package)
(define (make-real x)
  ((get 'make 'real) x))

; 複素数の直交座標パッケージと極座標パッケージ
; 直行座標の場合
(define (install-rectangular-package)
  ;;内部手続き
  (define (real-part z) (car z))
  (define (imag-part z) (cdr z))
  (define (make-from-real-imag x y) (cons x y))
  (define (magnitude z)
    (sqrt (+ (square (real-part z))
	     (square (imag-part z)))))
  (define (angle z)
    (atan (imag-part z) (real-part z)))
  (define (make-from-mag-ang r a)
    (cons (* r (cos a)) (* r (sin a))))
  ;; システムの他の部分とのインタフェース
  (define (tag x) (attach-tag 'rectangular x))
  (put 'real-part '(rectangular) real-part)
  (put 'imag-part '(rectangular) imag-part)
  (put 'magnitude '(rectangular) magnitude)
  (put 'angle '(rectangular) angle)
  (put 'make-from-real-imag 'rectangular
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'rectangular
       (lambda (r a) (tag (make-from-mag-ang r a))))
  'done)

; 極座標の場合
(define (install-polar-package)
  ;;内部手続き
  (define (magnitude z) (car z))
  (define (angle z) (cdr z))
  (define (make-from-mag-ang r a) (cons r a))
  (define (real-part z) 
    (* (magnitude z) (cos (angle z))))
  (define (imag-part z) 
    (* (magnitude z) (sin (angle z))))
  (define (make-from-real-imag x y) 
    (cons (sqrt (+ (square x) (square y)))
	  (atan y x)))
  ;; システムの他の部分とのインタフェース
  (define (tag x) (attach-tag 'polar x))
  (put 'real-part '(polar) real-part)
  (put 'imag-part '(polar) imag-part)
  (put 'magnitude '(polar) magnitude)
  (put 'angle '(polar) angle)
  (put 'make-from-real-imag 'polar
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'polar
       (lambda (r a) (tag (make-from-mag-ang r a))))
  'done)

; apply-generic を使った汎用選択子の定義
(define (real-part z) (apply-generic 'real-part z))
(define (imag-part z) (apply-generic 'imag-part z))
(define (magnitude z) (apply-generic 'magnitude z))
(define (angle z) (apply-generic 'angle z))
; パッケージの外部のプログラムから、それぞれの構成子を使用する
(define (make-from-real-imag x y)
  ((get 'make-from-real-imag 'rectangular) x y))
(define (make-from-mag-ang r a)
  ((get 'make-from-mag-ang 'polar) r a))

; 複素数
(define (install-complex-package)
  ;; 直交座標と極座標パッケージから取り入れた手続き
  (define (make-from-real-imag x y)
    ((get 'make-from-real-imag 'rectangular) x y))
  (define (make-from-mag-ang r a)
    ((get 'make-from-mag-ang 'polar) r a))
  ;; 内部手続き
  (define (add-complex z1 z2)
    (make-from-real-imag (+ (real-part z1) (real-part z2))
			 (+ (imag-part z1) (imag-part z2))))
  (define (sub-complex z1 z2)
    (make-from-real-imag (- (real-part z1) (real-part z2))
			 (- (imag-part z1) (imag-part z2))))
  (define (mul-complex z1 z2)
    (make-from-real-imag (* (magnitude z1) (magnitude z2))
			 (* (angle z1) (angle z2))))
  (define (div-complex z1 z2)
    (make-from-real-imag (/ (magnitude z1) (magnitude z2))
			 (- (angle z1) (angle z2))))
  (define (equ-complex z1 z2)
    (and (= (real-part z1) (real-part z2))
	 (= (imag-part z1) (imag-part z2))))
  (define (=zero-complex z)
    (and (= (real-part z) 0)
	 (= (imag-part z) 0)))
  ;; システムの他の部分へのインタフェース
  (define (tag z) (attach-tag 'complex z))
  (put 'add '(complex complex)
       (lambda (z1 z2) (tag (add-complex z1 z2))))
  (put 'sub '(complex complex)
       (lambda (z1 z2) (tag (sub-complex z1 z2))))
  (put 'mul '(complex complex)
       (lambda (z1 z2) (tag (mul-complex z1 z2))))
  (put 'div '(complex complex)
       (lambda (z1 z2) (tag (div-complex z1 z2))))
  (put 'make-from-real-imag 'complex
       (lambda (x y) (tag (make-from-real-imag x y))))
  (put 'make-from-mag-ang 'complex
       (lambda (r a) (tag (make-from-mag-ang r a))))
  (put 'equ? '(complex complex)
       (lambda (z1 z2) (equ-complex z1 z2)))
  (put '=zero? '(complex)
       (lambda (x) (=zero-complex x)))
  (put 'real-part '(complex) real-part)
  (put 'imag-part '(complex) imag-part)
  (put 'magnitude '(complex) magnitude)
  (put 'ange '(complex) angle)
  'done)
(define (make-complex-from-real-imag x y)
  ((get 'make-from-real-imag 'complex) x y))
(define (make-complex-from-mag-ang r a)
  ((get 'make-from-mag-ang 'complex) r a))

(install-integer-package)
(install-rational-package)
(install-real-package)
(install-rectangular-package)
(install-polar-package)
(install-complex-package)

テスト

(add (make-integer 3) (make-integer 4))
; gosh> (integer . 7)
(add (make-integer 3) (make-rational 3 4))
; gosh> (rational 15 . 4)
(add (make-integer 3) (make-real 4))
; gosh> (real . 7.0)
(add (make-integer 3) (make-complex-from-real-imag 3 4))
; gosh> (complex rectangular 6.0 . 4)
(add (make-integer 3) (make-complex-from-mag-ang 30 4))
; gosh> (complex rectangular -16.60930862590836 . -22.704074859237846)
(add (make-rational 3 4) (make-integer 3))
; gosh> (rational 15 . 4)
(add (make-real 4) (make-integer 3))
; gosh> (real . 7.0)
(add (make-complex-from-real-imag 3 4) (make-integer 3))
; gosh> (complex rectangular 6.0 . 4)
(add (make-complex-from-mag-ang 30 4) (make-integer 3))
; gosh> (complex rectangular -16.60930862590836 . -22.704074859237846)
(add (make-rational 3 4) (make-rational 4 3))
; gosh> (rational 25 . 12)
(add (make-rational 3 4) (make-real 4))
; gosh> (real . 4.75)
(add (make-rational 3 4) (make-complex-from-real-imag 3 4))
; gosh> (complex rectangular 3.75 . 4)
(add (make-rational 3 4) (make-complex-from-mag-ang 30 4))
; gosh> (complex rectangular -18.85930862590836 . -22.704074859237846)
(add (make-real 4) (make-rational 3 4))
; gosh> (real . 4.75)
(add (make-complex-from-real-imag 3 4) (make-rational 3 4))
; gosh> (complex rectangular 3.75 . 4)
(add (make-complex-from-mag-ang 30 4) (make-rational 3 4))
; gosh> (complex rectangular -18.85930862590836 . -22.704074859237846)
(add (make-real 3) (make-real 4))
; gosh> (real . 7.0)
(add (make-real 4) (make-complex-from-real-imag 3 4))
; gosh> (complex rectangular 7.0 . 4)
(add (make-real 4) (make-complex-from-mag-ang 30 4))
; gosh> (complex rectangular -15.609308625908358 . -22.704074859237846)
(add (make-complex-from-real-imag 3 4) (make-real 4))
; gosh> (complex rectangular 7.0 . 4)
(add (make-complex-from-mag-ang 30 4) (make-real 4))
; gosh> (complex rectangular -15.609308625908358 . -22.704074859237846)
(add (make-complex-from-real-imag 3 4) (make-complex-from-real-imag 4 3))
; gosh> (complex rectangular 7 . 7)
(add (make-complex-from-real-imag 3 4) (make-complex-from-mag-ang 30 4))
; gosh> (complex rectangular -16.60930862590836 . -18.704074859237846)
(add (make-complex-from-mag-ang 30 4) (make-complex-from-real-imag 3 4))
; gosh> (complex rectangular -16.60930862590836 . -18.704074859237846)
(add (make-complex-from-mag-ang 30 4) (make-complex-from-mag-ang 4 30))
; gosh> (complex rectangular -18.99230282635802 . -26.656201355609294)